MENU

• コンテンツ
  • プログラミング
  • エレクトロニクス
  • 家サーバ管理帳
  • Solaris Administrator
  • ごちゃ混ぜ実験
  • このサイトについて
    
• その他
  • サイトマップ
  • 人気ページ
  • 最新記事
    
• 掲示板・ゲストブック
  • FORUM
    
• リンク
  • ExattoSoftware
  • GitHub
    

Online: 2
Today: 2
Yesterday: 0
Total: 9558

はじめに †

OSの起動と同時にアプリケーションを起動したい場合は、「スタートアップ」に登録しておくと便利ですが、少し古いPCだと、ログオン中にまだHDDアクセスが続いているときに、スタートアップのアプリケーションが実行されるため、起動が遅く感じてしまいます。
ここでは、VBScriptを使って、アプリケーションの起動開始をわざと遅くするツールを作成しました。

ソースコード †

Option Explicit
'On Error Goto Next

'---------------------------------------------------------------------
' 遅延起動ツール
' by myasu
'---------------------------------------------------------------------

'ref: http://www.roy.hi-ho.ne.jp/mutaguchi/wsh/object/wshshell.htm


'---------------------------------------------------------------------
'変数の宣言
Dim objWSH
Dim ary_strCommand
Dim iDelay_Init
Dim iDelay_Next
Dim buf_strCommand


'---------------------------------------------------------------------
'各種設定変数

'起動したいアプリケーションの一覧（フルパスで記述）
ary_strCommand = Array(_
	"C:\Program Files\Mozilla Firefox\firefox.exe",_
	"C:\Program Files\Mozilla Thunderbird\thunderbird.exe",_
	"C:\Program Files\Mame5\Mame5.exe")


'起動開始するまでの待機時間(ms)
iDelay_Init = 20000

'次を起動するまでの待機時間(ms)
iDelay_Next = 5000


'---------------------------------------------------------------------
'メイン

'オブジェクトの確保
Set objWSH = Wscript.CreateObject("Wscript.Shell")

'起動開始まで待機
Wscript.Sleep iDelay_Init

'配列からコマンドを一つずつ取り出す
For Each buf_strCommand In ary_strCommand
	
'	WScript.Echo buf_strCommand
	
	'起動
	objWSH.Run Chr(34) & buf_strCommand & Chr(34), 1 , false
	
	'次を起動するまで待機
	Wscript.Sleep iDelay_Next
Next

説明 †

動き †

ary_strCommandに列挙したコマンドを、iDelay_Initミリ秒分待ってから起動します。
その際に、コマンドの実行は同時に行わず、iDelay_Nextミリ秒分待ってから順次起動します。

Run関数について †

1. 第一引数
   Run関数の引数に対し、"Chr(34)"で囲んでいるのは、buf_strCommandにスペースを含むコマンドがあった場合、引数エラーになるのを防ぐためです。
   
2. 第二引数
   

   値	動作
   0	非表示
   1	通常サイズ（省略時）
   2	最小化
   3	最大化
   4	通常サイズ,フォーカス無し
   6	最小化,フォーカス無し

3. 第三引数
   

   値	動作
   true	アプリケーションの終了を待ってから次の行を実行
   false	アプリケーションの終了を待たず次の行を実行

参考 †

• http://www.roy.hi-ho.ne.jp/mutaguchi/wsh/object/wshshell.htm
• http://www.atmarkit.co.jp/fwin2k/tutor/cformwsh06/cformwsh06_02.html

Prog